* DIODES INCORPORATED AND ITS AFFILIATED COMPANIES AND SUBSIDIARIES (COLLECTIVELY, "DIODES") 
* PROVIDE THESE SPICE MODELS AND DATA (COLLECTIVELY, THE "SM DATA") "AS IS" AND WITHOUT ANY 
* REPRESENTATIONS OR WARRANTIES, EXPRESS OR IMPLIED, INCLUDING ANY WARRANTY OF MERCHANTABILITY 
* OR FITNESS FOR A PARTICULAR PURPOSE, ANY WARRANTY ARISING FROM COURSE OF DEALING OR COURSE OF 
* PERFORMANCE, OR ANY WARRANTY THAT ACCESS TO OR OPERATION OF THE SM DATA WILL BE UNINTERRUPTED, 
* OR THAT THE SM DATA OR ANY SIMULATION USING THE SM DATA WILL BE ERROR FREE. TO THE MAXIMUM 
* EXTENT PERMITTED BY LAW, IN NO EVENT WILL DIODES BE LIABLE FOR ANY DIRECT OR INDIRECT, 
* SPECIAL, INCIDENTAL, PUNITIVE OR CONSEQUENTIAL DAMAGES ARISING OUT OF OR IN CONNECTION WITH 
* THE PRODUCTION OR USE OF SM DATA, HOWEVER CAUSED AND UNDER WHATEVER CAUSE OF ACTION OR THEORY 
* OF LIABILITY BROUGHT (INCLUDING, WITHOUT LIMITATION, UNDER ANY CONTRACT, NEGLIGENCE OR OTHER 
* TORT THEORY OF LIABILITY), EVEN IF DIODES HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES, 
* AND DIODES' TOTAL LIABILITY (WHETHER IN CONTRACT, TORT OR OTHERWISE) WITH REGARD TO THE SM 
* DATA WILL NOT, IN THE AGGREGATE, EXCEED ANY SUMS PAID BY YOU TO DIODES FOR THE SM DATA.


.subckt AZ431L ANODE CATHODE REF
D0 ANODE REF DIODE
Q38 CATHODE ANODE ANODE 0 n1
R1 REF Q25_B 4.2K
Q25 CATHODE Q25_B Q25_E 0 n1
R4 Q25_E R4_N 25.6K
R14 R4_N R14_N 89.6K
R3 R14_N R3_N 25.5K
R12 R3_N ANODE 76.8K
R13 R4_N Q28_B 4.2K
Q28 Q25_E Q28_B R33_P 0 n1
R33 R33_P R33_N 10.25K
R8 R33_N ANODE 132K
R27 Q29_E ANODE 222K
Q29 Q29_C R2_N Q29_E n1
R2 REF R2_N 960K
Q44 Q29_C Q29_C CATHODE 0 P1
Q45 Q29_E Q29_C CATHODE 0 P1
Q46 Q46_C Q29_C CATHODE 0 P1
Q47 Q47_C Q29_C CATHODE 0 P1
Q0 ANODE R14_N Q46_C 0 P1
Q1 ANODE R3_N Q47_C  0 P1
Q30 Q30_C Q47_C R28_P 0 n1 8
Q31 Q31_C Q46_C R28_P 0 n1
Q49 Q30_C Q30_C CATHODE 0 P1
Q48 Q31_C Q30_C CATHODE 0 P1
R28 R28_P ANODE 6.5K
C0 Q31_C R17_P 26p
Q27 R17_P Q31_C CATHODE 0 P1
R17 R17_P ANODE 33K
Q33 Q33_C R17_P R23_P 0 n1
R23 R23_P ANODE 865
Q52 Q33_C Q33_C CATHODE 0 P1
Q51 Q51_C Q33_C CATHODE 0 P1 10
Q37 Q51_C Q51_C R23_P 0 n1 20
Q35 CATHODE Q51_C ANODE 0 n1 100
.model p1 pnp bf=50
.model n1 npn bf=100 tf=2n cjc=1p is=5e-18 NF=1.07
.model diode d rs=1 cjo=2p
.ends


*ZETEX ZR431L Spice Model v1.0 Last Revised 21/10/05
    *
    *NOTE: This is a simplified model.  Do not rely on this model for 
    *validation of circuit stability.  It does not accurately replicate 
    *stability boundary conditions when the device is operated with 
    *additional load capacitance.  Check the circuit stability by normal 
    *breadboarding techniques.
    *
    .SUBCKT ZR431L 1 2 3
    *Connections  Vz Vref Gnd
    *
    *Input current
    Rin 2 3 Rmod1 1.127E7
    D1 3 2 Dmod1
    D2 2 1 Dmod1
    Cin 2 3 10E-12
    *
    *Quiescent current
    E1 50 3 2 3 1
    D8 50 51 Dmod1
    Rq 51 52 Rmod4 31E3
    Vq 52 3 0
    F1 1 3 Vq 1
    Ro 1 3 1.5E6
    *
    *Reference voltage
    Iref 3 21 1.2405E-3
    Rref 21 3 Rmod2 1000
    *
    *Voltage dependence
    G1 21 3 POLY(1) 1 3 0 1.57E-6 -0.97e-7
    *
    *Gain
    G2 3 31 2 21 1e-7
    Rt2  3 31 100E6
    Rt3  3 32 3E6
    Ct1 31 32 3E-13
    D3 31 3  Dmod1
    D4 3 31  Dmod1
    *
    *Output
    *Q1 5 42 3 Qmod1
    Cr1 7 31 1.5e-14
    G3 41 3 31 3 0.8
    Rc1 6 7 5
    Rc2 7 5 5
    D6 3 41 Dmod1
    D7 3 1 Dmod1
    L1 1 6 10nH
    D9 5 41 Dmod2
    *
    .MODEL Qmod1 NPN BF=220 CJC=3E-12 CJE=3E-12
    .MODEL Rmod1 RES (TC1=2.95E-3 TC2=-5E-7)
    .MODEL Rmod2 RES (TC1=1.5e-5 TC2=-3.5e-7)
    .MODEL Rmod3 RES (TC1=-2.5E-3 TC2=2E-5)
    .MODEL Rmod4 RES (TC1=1.7E-3 TC2=0)
    .MODEL Dmod1 D IS=5E-15 RS=4 BV=22
    .MODEL Dmod2 D IS=1E-18 RS=.01
    .ENDS  ZR431L
    *
    *$
    *